在日常办公中，我们经常会遇到excel导出问题。

今天我来给大家介绍，将excel每个工作表另存为单个 PDF

第一步：打开文件

按ALT + F11 打开Excel的VBA编辑器

第二步：选中左侧任意一个sheet双击

第三步：粘贴 魔法代码

Sub SaveEachWorksheetAsPDF()  
    Dim ws As Worksheet  
    Dim filePath As String  
    Dim pdfName As String  
    Dim folderPicker As FileDialog  
      
    ' 创建一个文件夹选择对话框  
    Set folderPicker = Application.FileDialog(msoFileDialogFolderPicker)  
      
    ' 显示对话框并等待用户选择一个文件夹  
    With folderPicker  
        .Title = "请选择保存PDF的文件夹"  
        .AllowMultiSelect = False  
          
        ' 如果用户点击了"取消"按钮，则退出  
        If .Show = -1 Then  
            filePath = .SelectedItems(1)  
        Else  
            MsgBox "操作已取消。", vbExclamation  
            Exit Sub  
        End If  
    End With  
      
    ' 遍历工作簿中的每个工作表  
    For Each ws In ThisWorkbook.Worksheets  
        ' 设置文件名（不包含扩展名）  
        pdfName = filePath & "\" & Replace(ws.Name, " ", "") & ".pdf" ' 移除空格（如果需要）  
          
        ' 将工作表保存为PDF  
        ws.ExportAsFixedFormat _  
            Type:=xlTypePDF, _  
            Filename:=pdfName, _  
            Quality:=xlQualityStandard, _  
            IncludeDocProperties:=True, _  
            IgnorePrintAreas:=False, _  
            OpenAfterPublish:=False  
    Next ws  
      
    ' 提示用户所有工作表已保存为PDF  
    MsgBox "所有工作表已保存为PDF。", vbInformation  
End Sub

第四步：点击菜单栏 运行=>运行子程序和用户窗口

第五步：选择保存PDF的文件夹

【插入效果】等待中

第六步：弹出提示框 运行结束

我们可以看到针对excel中的每个工作表导出了单个pdf

总结

以上就是今天要讲的内容，本文介绍excel工作表导出单独的pdf，赶紧上手试试吧。

如果觉得有用欢迎点赞，关注
有问题留言我！！